
        H.323 Uniform Resource Locator (URL) Scheme Registration

Status of this Memo

   This memo provides information for the Internet community.  It does
   not specify an Internet standard of any kind.  Distribution of this
   memo is unlimited.

Copyright Notice

   Copyright (C) The Internet Society (2003).  All Rights Reserved.

Abstract

   ITU-T Recommendation H.323 version 4 introduced an H.323-specific
   Uniform Resource Locator (URL).  This document reproduces the H323-
   URL definition found in H.323, and is published as an RFC for ease of
   access and registration with the Internet Assigned Numbers Authority
   (IANA).

Conventions used in this document

   The key words "MUST", "MUST NOT", "REQUIRED", "SHALL", "SHALL NOT",
   "SHOULD", "SHOULD NOT", "RECOMMENDED", "MAY", and "OPTIONAL" in this
   document are to be interpreted as described in BCP 14, RFC 2119 [2].

Table of Contents

   1. Introduction...................................................2
   2. URL Scheme Formal Syntax Definition and Character Encoding.....2
   3. Intended Usage.................................................3
   4. Applications and/or protocols, which may use H.323 URL scheme..3
   5. Security Considerations........................................3
   6. IANA Considerations............................................4
   References........................................................4
   Acknowledgments...................................................5
   Author's Address..................................................5
   Full Copyright Statement..........................................6








Levin                        Informational                      [Page 1]

RFC 3508                    H.323 URL Scheme                  April 2003


1.   Introduction

   ITU-T Recommendations H.323 [3] and H.225.0 [4] define a system for
   multimedia communications services over packet based networks.
   H.225.0 [4] defines an alias type for carrying any standard Uniform
   Resource Locator (URL).  H.323 version 4 [3] introduced an H.323-
   specific URL, which may be used to resolve the address of a network
   entity to which H.323 calls may be directed.

   This document reproduces the H323-URL definition found in ITU-T
   recommendation H.323 [3] and is published as an RFC for ease of
   access and IANA registration.

2.   URL Scheme Formal Syntax Definition and Character Encoding

   The H.323 URL is defined in ABNF as shown below.  Note that it
   utilizes the Core Rules specified in section 6.1 of [2].

   H323-URL    =   "h323:" address [ url-parameters ]
   address     =   user / "@" hostport / user "@" hostport
   user        =   1*(%x21-24 / %x26-3F / %x41-7F / escaped)
                        ; The symbols "%", "@", and symbols with
                        ; a character value below 0x21 may be
                        ; represented as escaped sequences.
   hostport    =   host [ ":" port]
   host        =   hostname / IPv4address / IPv6reference
   hostname    =   *( domainlabel "." ) toplabel [ "." ]
   domainlabel =   alphanum / alphanum *( alphanum / "-" ) alphanum
   toplabel    =   ALPHA / ALPHA *( alphanum / "-" ) alphanum
   IPv4address =   1*3DIGIT "." 1*3DIGIT "." 1*3DIGIT "." 1*3DIGIT
   IPv6reference   =  "[" IPv6address "]"
   IPV6address =   hexpart [ ":" IPv4address ]
   hexpart     =   hexseq / hexseq "::" [ hexseq ] / "::" [ hexseq ]
   hexseq      =   hex4 *( ":" hex4 )
   hex4        =   1*4HEXDIG
   port        =   1*DIGIT
   url-parameters  =   *( ";" url-parameter )
   url-parameter   =   1*(%x21-24 / %x26-3A / %x3C-7F / escaped)
                          ; Specific parameter definitions are for
                          ; further study.
                          ; The symbols "%", ";", and symbols
                          ; with a character value below 0x21 may be
                          ; represented as escaped sequences.
   alphanum    =   ALPHA / DIGIT
   escaped     =   "%" HEXDIG HEXDIG

   The host is case insensitive.

   The "user" is a Unicode [8] string that shall be UTF-8 [7] encoded
   and then escaped as necessary.  In the "user" field, the characters
   with a numeric value below 0x80 are case insensitive and the
   characters with a numeric value above or equal to 0x80 are case
   sensitive.

   The character set and case sensitivity of the "url-parameter" is
   specified in each parameter definition.

3.   Intended Usage

   The H.323 URL is intended to help an entity resolve the address of
   another H.323 entity, where an "entity" may be a user, a device, or a
   service.  The "user" portion of the URL specifies an alias for the
   entity, without carrying any information about the location of the
   entity.  The "hostport", on the other hand, is the domain name of an
   Endpoint, Gatekeeper, Border Element, or other functional element to
   which H.323 calls may be directed or for which services may be
   performed.

4.   Applications and/or protocols, which may use H.323 URL scheme

   H.323 URLs may be carried by other protocols, such as SIP [6] or TRIP
   [9].  H.323 URLs may be also contained within web pages or within XML
   data, which may be utilized by H.323 entities in order to initiate
   calls or perform services.

5.   Security Considerations

   When an H.323 URL is carried within H.225.0 [4] messages, security is
   addressed by the H.235 security framework [5].  When an H.323 URL
   carried within other protocols (such as SIP [6]), the security is
   addressed within the corresponding protocol.

   In general, security, as it relates to the usage and carriage of the
   H.323 URLs, is considered as an issue that should be addressed within
   scope of H.323 or other relevant protocols and is not within the
   scope of this document.

6.   IANA Considerations

   The purpose of this document is serving as a reference point for the
   purposes of registering the H.323 URL scheme with IANA.

   Having the URL registered with IANA will ensure that there is no
   duplication of the URL scheme "h323".  This document reproduces the
   exact H323-URL definition as published in ITU-T Recommendation H.323
   [3].

   Registration Template

      URL scheme name: h323

      URL scheme syntax: Section 2 of RFC 3508

      Character encoding considerations: Section 2 of RFC 3508

      Intended usage: Section 3 of RFC 3508

      Applications and/or protocols which use this scheme: Section 4 of
      RFC 3508

      Interoperability considerations: None.  (Section 2 of RFC 3508
      contains the first version of "h323" URL definition.)

      Security considerations: Section 5 of RFC 3508

      Relevant publications: [3] and [4]

      Contact: Orit Levin, orit@radvision.com

      Author/Change Controller: IESG

Full Copyright Statement

   Copyright (C) The Internet Society (2003).  All Rights Reserved.

   This document and translations of it may be copied and furnished to
   others, and derivative works that comment on or otherwise explain it
   or assist in its implementation may be prepared, copied, published
   and distributed, in whole or in part, without restriction of any
   kind, provided that the above copyright notice and this paragraph are
   included on all such copies and derivative works.  However, this
   document itself may not be modified in any way, such as by removing
   the copyright notice or references to the Internet Society or other
   Internet organizations, except as needed for the purpose of
   developing Internet standards in which case the procedures for
   copyrights defined in the Internet Standards process must be
   followed, or as required to translate it into languages other than
   English.

   The limited permissions granted above are perpetual and will not be
   revoked by the Internet Society or its successors or assigns.

   This document and the information contained herein is provided on an
   "AS IS" basis and THE INTERNET SOCIETY AND THE INTERNET ENGINEERING
   TASK FORCE DISCLAIMS ALL WARRANTIES, EXPRESS OR IMPLIED, INCLUDING
   BUT NOT LIMITED TO ANY WARRANTY THAT THE USE OF THE INFORMATION
   HEREIN WILL NOT INFRINGE ANY RIGHTS OR ANY IMPLIED WARRANTIES OF
   MERCHANTABILITY OR FITNESS FOR A PARTICULAR PURPOSE.

